Excel VBA gebruiken om SQL Query

Ik ben redelijk nieuw voor SQL en VBA. Ik heb een SQL-query geschreven die ik zou willen bellen en rennen vanaf een VBA-sub in een Excel-werkmap en vervolgens de queryresultaten in de werkmap brengen. Ik heb wat subs online gevonden (Stackoverflow en andere plaatsen) die beweren dit te doen, maar ik heb problemen met het begrijpen ervan omdat ze geen uitleg bevatten. Hier is bijvoorbeeld een sub die ik online heb gevonden:

Sub ConnectSqlServer()
    Dim conn As ADODB.Connection
    Dim rs As ADODB.Recordset
    Dim sConnString As String
    ' Create the connection string.
    sConnString = "Provider=SQLOLEDB;Data Source=INSTANCE\SQLEXPRESS;" & _
                  "Initial Catalog=MyDatabaseName;" & _
                  "Integrated Security=SSPI;"
    ' Create the Connection and Recordset objects.
    Set conn = New ADODB.Connection
    Set rs = New ADODB.Recordset
    ' Open the connection and execute.
    conn.Open sConnString
    Set rs = conn.Execute("SELECT * FROM Table1;")
    ' Check we have data.
    If Not rs.EOF Then
        ' Transfer result.
        Sheets(1).Range("A1").CopyFromRecordset rs
    ' Close the recordset
        rs.Close
    Else
        MsgBox "Error: No records returned.", vbCritical
    End If
    ' Clean up
    If CBool(conn.State And adStateOpen) Then conn.Close
    Set conn = Nothing
    Set rs = Nothing
End Sub

Allereerst, zou dit werken? Ten tweede, wat moet ik in de sub vervangen (het lijkt op provider, gegevensbron, begincatalogus, enz.) En waar vind ik de info om ze te vervangen?

Ik hoop dat deze vraag niet te verwarrend is en ik waardeer uw hulp!

Antwoord 1, Autoriteit 100%

Hieronder staat code die ik momenteel gebruik om gegevens van een MS SQL Server 2008 naar VBA te trekken. U moet ervoor zorgen dat u de juiste ADODB-referentie [VBA Editor->Tools->Referenties] heeft en ervoor zorgen dat Microsoft ActiveX Data Objects 2.8 Libraryis aangevinkt, dat is de tweede van de onderste rij die is aangevinkt (ik gebruik Excel 2010 op Windows 7; je hebt misschien een iets andere ActiveX-versie, maar deze begint nog steeds met Microsoft ActiveX):

Submodule voor verbinding met MS SQL met externe host & Gebruikersnaam/wachtwoord

Sub Download_Standard_BOM()
'Initializes variables
Dim cnn As New ADODB.Connection
Dim rst As New ADODB.Recordset
Dim ConnectionString As String
Dim StrQuery As String
'Setup the connection string for accessing MS SQL database
   'Make sure to change:
       '1: PASSWORD
       '2: USERNAME
       '3: REMOTE_IP_ADDRESS
       '4: DATABASE
    ConnectionString = "Provider=SQLOLEDB.1;Password=PASSWORD;Persist Security Info=True;User ID=USERNAME;Data Source=REMOTE_IP_ADDRESS;Use Procedure for Prepare=1;Auto Translate=True;Packet Size=4096;Use Encryption for Data=False;Tag with column collation when possible=False;Initial Catalog=DATABASE"
    'Opens connection to the database
    cnn.Open ConnectionString
    'Timeout error in seconds for executing the entire query; this will run for 15 minutes before VBA timesout, but your database might timeout before this value
    cnn.CommandTimeout = 900
    'This is your actual MS SQL query that you need to run; you should check this query first using a more robust SQL editor (such as HeidiSQL) to ensure your query is valid
    StrQuery = "SELECT TOP 10 * FROM tbl_table"
    'Performs the actual query
    rst.Open StrQuery, cnn
    'Dumps all the results from the StrQuery into cell A2 of the first sheet in the active workbook
    Sheets(1).Range("A2").CopyFromRecordset rst
End Sub