Wat is de opdracht of de snelste manier om resultaten naar de console te sturen met vbscript?
Antwoord 1, autoriteit 100%
Je bedoelt:
Wscript.Echo "Like this?"
Als u dat uitvoert onder wscript.exe(de standaardhandler voor de .vbs-extensie, dus wat u krijgt als u dubbelklikt op het script), krijgt u een “MessageBox” dialoog met uw tekst erin. Als u dat uitvoert onder cscript.exe, krijgt u uitvoer in uw consolevenster.
Antwoord 2, autoriteit 21%
Dit is gevonden op Dragon -IT-scripts en codeopslag.
Je kunt dit als volgt doen en wegblijven van de cscript/wscript-verschillen en je in staat stellen dezelfde console-uitvoer te krijgen die een batchbestand zou hebben. Dit kan helpen als je VBS aanroept vanuit een batchbestand en het er naadloos uit moet laten zien.
Set fso = CreateObject ("Scripting.FileSystemObject")
Set stdout = fso.GetStandardStream (1)
Set stderr = fso.GetStandardStream (2)
stdout.WriteLine "This will go to standard output."
stderr.WriteLine "This will go to error output."
Antwoord 3, autoriteit 7%
Je hoeft alleen cscript te forceren in plaats van wscript. Ik gebruik altijd dit sjabloon. De functie ForceConsole() zal je vbs in cscript uitvoeren, ook heb je een mooie alias om tekst af te drukken en te scannen.
Set oWSH = CreateObject("WScript.Shell")
vbsInterpreter = "cscript.exe"
Call ForceConsole()
Function printf(txt)
WScript.StdOut.WriteLine txt
End Function
Function printl(txt)
WScript.StdOut.Write txt
End Function
Function scanf()
scanf = LCase(WScript.StdIn.ReadLine)
End Function
Function wait(n)
WScript.Sleep Int(n * 1000)
End Function
Function ForceConsole()
If InStr(LCase(WScript.FullName), vbsInterpreter) = 0 Then
oWSH.Run vbsInterpreter & " //NoLogo " & Chr(34) & WScript.ScriptFullName & Chr(34)
WScript.Quit
End If
End Function
Function cls()
For i = 1 To 50
printf ""
Next
End Function
printf " _____ _ _ _____ _ _____ _ _ "
printf "| _ |_| |_ ___ ___| |_ _ _ _| | | __|___ ___|_|___| |_ "
printf "| | | '_| . | | --| | | | . | |__ | _| _| | . | _|"
printf "|__|__|_|_,_|___|_|_|_____|_____|___| |_____|___|_| |_| _|_| "
printf " |_| v1.0"
printl " Enter your name:"
MyVar = scanf
cls
printf "Your name is: " & MyVar
wait(5)
Antwoord 4, autoriteit 2%
Ik kwam dit bericht tegen en ging terug naar een aanpak die ik enige tijd geleden gebruikte en die vergelijkbaar is met die van @MadAntrax.
Het belangrijkste verschil is dat het een door de gebruiker gedefinieerde VBScript-klasse gebruikt om alle logica in te pakken voor het overschakelen naar CScript en het uitvoeren van tekst naar de console, zodat het hoofdscript een beetje schoner wordt.
Hierbij wordt ervan uitgegaan dat het uw doel is om uitvoer naar de console te streamen, in plaats van dat de uitvoer naar berichtvensters gaat.
De cCONSOLE-klasse staat hieronder. Om het te gebruiken, voegt u de volledige klasse toe aan het einde van uw script en start u het direct aan het begin van het script. Hier is een voorbeeld:
Option Explicit
'// Instantiate the console object, this automatically switches to CSCript if required
Dim CONS: Set CONS = New cCONSOLE
'// Now we can use the Consol object to write to and read from the console
With CONS
'// Simply write a line
.print "CSCRIPT Console demo script"
'// Arguments are passed through correctly, if present
.Print "Arg count=" & wscript.arguments.count
'// List all the arguments on the console log
dim ix
for ix = 0 to wscript.arguments.count -1
.print "Arg(" & ix & ")=" & wscript.arguments(ix)
next
'// Prompt for some text from the user
dim sMsg : sMsg = .prompt( "Enter any text:" )
'// Write out the text in a box
.Box sMsg
'// Pause with the message "Hit enter to continue"
.Pause
End With
'= =========== End of script - the cCONSOLE class code follows here
Hier is de code voor de cCONSOLE-klasse
CLASS cCONSOLE
'= =================================================================
'=
'= This class provides automatic switch to CScript and has methods
'= to write to and read from the CSCript console. It transparently
'= switches to CScript if the script has been started in WScript.
'=
'= =================================================================
Private oOUT
Private oIN
Private Sub Class_Initialize()
'= Run on creation of the cCONSOLE object, checks for cScript operation
'= Check to make sure we are running under CScript, if not restart
'= then run using CScript and terminate this instance.
dim oShell
set oShell = CreateObject("WScript.Shell")
If InStr( LCase( WScript.FullName ), "cscript.exe" ) = 0 Then
'= Not running under CSCRIPT
'= Get the arguments on the command line and build an argument list
dim ArgList, IX
ArgList = ""
For IX = 0 to wscript.arguments.count - 1
'= Add the argument to the list, enclosing it in quotes
argList = argList & " """ & wscript.arguments.item(IX) & """"
next
'= Now restart with CScript and terminate this instance
oShell.Run "cscript.exe //NoLogo """ & WScript.ScriptName & """ " & arglist
WScript.Quit
End If
'= Running under CScript so OK to continue
set oShell = Nothing
'= Save references to stdout and stdin for use with Print, Read and Prompt
set oOUT = WScript.StdOut
set oIN = WScript.StdIn
'= Print out the startup box
StartBox
BoxLine Wscript.ScriptName
BoxLine "Started at " & Now()
EndBox
End Sub
'= Utility methods for writing a box to the console with text in it
Public Sub StartBox()
Print " " & String(73, "_")
Print " |" & Space(73) & "|"
End Sub
Public Sub BoxLine(sText)
Print Left(" |" & Centre( sText, 74) , 75) & "|"
End Sub
Public Sub EndBox()
Print " |" & String(73, "_") & "|"
Print ""
End Sub
Public Sub Box(sMsg)
StartBox
BoxLine sMsg
EndBox
End Sub
'= END OF Box utility methods
'= Utility to center given text padded out to a certain width of text
'= assuming font is monospaced
Public Function Centre(sText, nWidth)
dim iLen
iLen = len(sText)
'= Check for overflow
if ilen > nwidth then Centre = sText : exit Function
'= Calculate padding either side
iLen = ( nWidth - iLen ) / 2
'= Generate text with padding
Centre = left( space(iLen) & sText & space(ilen), nWidth )
End Function
'= Method to write a line of text to the console
Public Sub Print( sText )
oOUT.WriteLine sText
End Sub
'= Method to prompt user input from the console with a message
Public Function Prompt( sText )
oOUT.Write sText
Prompt = Read()
End Function
'= Method to read input from the console with no prompting
Public Function Read()
Read = oIN.ReadLine
End Function
'= Method to provide wait for n seconds
Public Sub Wait(nSeconds)
WScript.Sleep nSeconds * 1000
End Sub
'= Method to pause for user to continue
Public Sub Pause
Prompt "Hit enter to continue..."
End Sub
END CLASS
Antwoord 5, Autoriteit 2%
Er zijn vijf manieren om tekst naar de console uit te voeren:
Dim StdOut : Set StdOut = CreateObject("Scripting.FileSystemObject").GetStandardStream(1)
WScript.Echo "Hello"
WScript.StdOut.Write "Hello"
WScript.StdOut.WriteLine "Hello"
Stdout.WriteLine "Hello"
Stdout.Write "Hello"
WScript.Echo wordt uitgevoerd naar de console, maar alleen als het script is gestart met CScript.exe. Het wordt uitgevoerd naar berichtvakken indien begon met het gebruik van WScript.exe.
wscript.stdout.write en wscript.stdout.writine wordt altijd uitgevoerd naar de console.
stdout.write en stdout.writine wordt ook altijd uitgevoerd naar console. Het vereist extra objectcreatie, maar het is ongeveer 10% sneller dan WScript.Echo.
Antwoord 6
Maak een .vbs met de volgende code, waarmee je hoofd-.vbs wordt geopend:
Set objShell = WScript.CreateObject("WScript.shell")
objShell.Run "cscript.exe ""C:\QuickTestb.vbs"""
Hier is mijn belangrijkste .vbs
Option Explicit
Dim i
for i = 1 To 5
Wscript.Echo i
Wscript.Sleep 5000
Next